Response body: JSON value is equal or greater than

[Marek_Melocik]

Yes - also a solution.

Maybe a one more hint - not necessarily in this case. If you had more values to verify, you’d use for-each loop for verification. It is more clear and elegant solution.

def totalValue = parsedJson.total
def availableValue = parsedJson.available
def pendingValue = parsedJson.pending
def paidValue = parsedJson.paid

List vals = Arrays.asList(totalValue, availableValue, pendingValue, paidValue)

for(def val in vals) {
	CustomKeywords.'verify.VerifyValues.valueIsPresent'(val)
	CustomKeywords.'verify.VerifyValues.valueIsEqualOrGreaterThan'(val)
}

[alexfeel]

@Marek_Melocik

Maybe a one more hint - not necessarily in this case. If you had more values to verify, you’d use for-each loop for verification. It is more clear and elegant solution.

Oh, yes, you’re totally right! Thanks!

[Ibus]

@alexfeel

def totalValue = parsedJson.total

The code looks nice … but you have a small problem.
If one of the keys is not present in the response … the code will crash exactly there, at the def
So … you have to improve it a bit, either use json schema validation to check the keys presence, or when you declare the variables, use safe coding. Elvis operator may help:

def totalValue = parsedJson.total ?: 'missing'
-----------------------
	@Keyword
	def valueIsPresent(BigDecimal jsonValue) {
		if(jsonValue == 'missing') {
			KeywordUtil.markFailed("Key is not present")
		}
	}

[alexfeel]

@Ibus

If one of the keys is not present in the response

Yes, I’ve already faced that, so thank you again

[Ibus]

Also, there is another inconvenient.
If any of the key is not present (or have the wrong value) the execution will stop and the other’s verification skipped.
So you have to use also failure handling if this is a problem for you, see:
https://docs.katalon.com/katalon-studio/docs/failure-handling.html

[alexfeel]

@Ibus

@Keyword

I think I have to use:

	@Keyword
	def valueIsPresent(BigDecimal jsonValue) {
		if(jsonValue == 'missing' || jsonValue == null) {
			KeywordUtil.markFailed("Key is not present")
		}
	}

And I see another problem… Oh, while I was typing a message you’ve already describe it

[Ibus]

@alexfeel

if(jsonValue == ‘missing’ || jsonValue == null)

this is redundant if you use elvis, see:
http://groovy-lang.org/operators.html#_elvis_operator

the ‘?:’ will do exactly this for you, if null or empty will assign the value from the right to the variable

[alexfeel]

@Ibus

the ‘?:’ will do exactly this for you, if null or empty will assign the value from the right to the variable

Oh, it’s like a ternary operator in JS, it seems that for me the holidays have not ended yet

[Ibus]

Yeah, is a ternary on steroids

[alexfeel]

@Ibus

a ternary on steroids

[alexfeel]

@Ibus,

I don’t know why but if I get such response:

{
  "total":6.98,
  "available":0.0,
  "pending":0.0,
  "paid":6.98
}

At the line:

def availableValue = parsedJson.available ?: 'missing'

I get 'missing' instead of expected value and of course than:

ERROR k.k.c.m.CustomKeywordDelegatingMetaClass - ? No signature of method: verify.VerifyValues.valueIsPresent() is applicable for argument types: (java.lang.String) values: [missing]
Possible solutions: valueIsPresent(java.math.BigDecimal)

and so on…

[Ibus]

@alexfeel

valueIsPresent(BigDecimal jsonValue)

My bad. ‘missing’ is a string and your keyword expect a BigDecimal.
Use another safe value instead … e. g -1

the failure in fact appears here, when trying to compare the BigDecimal with the string:

if(jsonValue == 'missing')

[alexfeel]

@Ibus

e. g -1

It seems it’s some kind of another problem because of after changing to def availableValue = parsedJson.available ?: -1 I get:

ERROR k.k.c.m.CustomKeywordDelegatingMetaClass - ? com.kms.katalon.core.exception.StepFailedException: Key has incorrect value

It seems to me at the line def availableValue = parsedJson.available ?: -1 availableValue always gets -1 value if the response is "available":0.0.

[Ibus]

chh … i think groovy truth is playing with you, since 0 will evaluate to false:
http://docs.groovy-lang.org/latest/html/documentation/core-semantics.html#Groovy-Truth

So it may be solved with the plain ternary:

availableValue = (parsedJson.available!=null) ? parsedJson.available : -1.0

Sometime, abusing on steroids is a bad idea!

LE: on the other side we just find out that , using the Elvis, you can collapse your code to use a single keyword, like keyIsPresentAndGreatherThanZero since 0.0 will always be false

[alexfeel]

@Ibus

keyIsPresentAndGreatherThanZero

You’re right And I still have to use the plain ternary since I need to verify if the value is equal or greater than zero

@Ibus

availableValue = (parsedJson.available!=null) ? parsedJson.available : -1.0

Thanks!

---

Thanks to all at now my keywords are:

...

class VerifyValues {
	@Keyword
	def valueIsPresent(BigDecimal jsonValue) {
		if(jsonValue == -1.0) {
			KeywordUtil.markFailedAndStop("Key is not present")
		}
	}
	@Keyword
	def valueIsEqualOrGreaterThan(BigDecimal jsonValue) {
		BigDecimal cBase = 0.0
		if(jsonValue.compareTo(cBase) == -1) {
			KeywordUtil.markFailedAndStop("Key has incorrect value")
		}
	}
}

And verification code is:

...

'Set variables'

String jsonString = response.getResponseText()

JsonSlurper slurper = new JsonSlurper()
Map parsedJson = slurper.parseText(jsonString)

def totalValue = (parsedJson.total != null) ? parsedJson.total : -1.0
def availableValue = (parsedJson.available != null) ? parsedJson.available : -1.0
def pendingValue = (parsedJson.pending != null) ? parsedJson.pending : -1.0
def paidValue = (parsedJson.paid != null) ? parsedJson.paid : -1.0

List values = Arrays.asList(totalValue, availableValue, pendingValue, paidValue)

'Verify if all keys are present and their values are correct'

for(def val in values) {
	CustomKeywords.'verify.VerifyValues.valueIsPresent'(val)
	CustomKeywords.'verify.VerifyValues.valueIsEqualOrGreaterThan'(val)
}

[Marek_Melocik]

The power of cooperation. Nice!

[Ibus]

I played a bit in IDEA (i cannot make KatalonGUI to work properly in Linux … yet).
Maybe you can use this too:

import groovy.json.JsonSlurper

jsonString = """
{
  "total":6.98,
  "available":0.0,
  "pending":0.0
}
"""

//'Set variables'
//
//String jsonString = response.getResponseText()
//
JsonSlurper slurper = new JsonSlurper()
Map parsedJson = slurper.parseText(jsonString)

List keysToCheck = Arrays.asList('total', 'available', 'pending', 'paid')
keysToCheck.each { it ->
    valToCheck = (parsedJson.get(it) != null) ? parsedJson.get(it) : -1.0
    println("${it} : ${valToCheck}")
    //    CustomKeywords.'verify.VerifyValues.valueIsPresent'(valToCheck)
    //    CustomKeywords.'verify.VerifyValues.valueIsEqualOrGreaterThan'(valToCheck)
}

OUTPUT
total : 6.98
available : 0.0
pending : 0.0
paid : -1.0

For the complete Json the output is:

total : 6.98
available : 0.0
pending : 0.0
paid : 6.98

[Ibus]

More ‘groovyfication’ (We don’t need def or explicit types in a groovy script . Also, it is the default iterator so we can get rid of it)

slurper = new JsonSlurper()
parsedJson = slurper.parseText(jsonString)

keysToCheck = ['total', 'available', 'pending', 'paid']

keysToCheck.each {
    valToCheck = (parsedJson.get(it) != null) ? parsedJson.get(it) : -1.0
    println("${it} : ${valToCheck}")
    //    CustomKeywords.'verify.VerifyValues.valueIsPresent'(valToCheck)
    //    CustomKeywords.'verify.VerifyValues.valueIsEqualOrGreaterThan'(valToCheck)
}

[alexfeel]

@Ibus,

I have this keyword:

class VerifyValues {
	@Keyword
	def valueIsPresentAndIsEqualOrGreaterThan(BigDecimal jsonValue) {
		if(jsonValue == -1.0) {
			KeywordUtil.markFailedAndStop("Key is not present")
		}
		BigDecimal cBase = 0.0
		if(jsonValue.compareTo(cBase) == -1) {
			KeywordUtil.markFailedAndStop("Key has incorrect value")
		}
	}
}

And this verification code:

JsonSlurper slurper = new JsonSlurper()
parsedJson = slurper.parseText(jsonString)

keysToCheck = ['total', 'available', 'pending', 'paid']

keysToCheck.each { it ->
    valToCheck = (parsedJson.get(it) != null) ? parsedJson.get(it) : -1.0
    println("${it} : ${valToCheck}")
	CustomKeywords.'verify.VerifyValues.valueIsPresentAndIsEqualOrGreaterThan'(valToCheck)
}

If my input is one of those variation all works fine:

String jsonString = '''{
	"total":6.98,
	"available":0.0,
	"pending":-20.0,
	"paid":6.98
}'''

or

String jsonString = '''{
	"total":6.98,
	"available":0.0,
	"pendingssssssssss":0.0,
	"paid":6.98
}'''

But if I use:

String jsonString = '''{
	"total":6.98,
	"available":0.0,
	"pending":-1.0,
	"paid":6.98
}'''

I get Key is not present because it matches -1.0 in valToCheck = (parsedJson.get(it) != null) ? parsedJson.get(it) : -1.0

Well I can use some other number and hope that there will never be matches.

And if I use:

String jsonString = '''{
	"total":6.98,
	"available":0.0,
	"pending":,
	"paid":6.98
}'''

I get:

Verification FAILED Reason: groovy.json.JsonException: Unable to determine the current character, it is not a string, number, array, or object

In this way parsedJson.get(it) != null is not processed correctly. I think I don’t understand something

[Ibus]

I was expecting this

With case by case verification, more situations can occur (as you just find out, value missing, or value is a string etc etc)

Therefore … JSON schema validation to the rescue, otherwise you will have to treat all such edge cases and the code will start to be full of exceptions

If not in hurry, tomorrow I will be back at work and i will share again the code of the keyword I use (I am lazy today to re-write it)

the last error you get is due to a malformed Json.